1C ЗУП 3.1 - Механизм представлений

23.11.2025

Тема "механизма представлений" уже избитая, в сети есть много статей и вебинаров, подробно описывать смысла здесь нет, статья имеет характер шпаргалки для достаточно опытных разработчиков, а также содержит некоторые практические сведения, не раскрытые в других популярных статьях в интернете.

Содержание

• Классическая схема механизма представлений в 1С ЗУП, как его применять на СКД
• Как применять механизм представлений при формировании любого запроса

• Представления_Периоды
• Представления_КадровыеДанныеСотрудников
• Представления_КадровыеДанныеФизическихЛиц
• Представления_СотрудникиОрганизации
• Представления_РабочиеМестаСотрудников
• Представления_ШтатноеРасписание

Как работает механизм представлений в 1С ЗУП, и как его применять

Схема работы механизма представлений, которую любят рисовать в статьях на эту тему (постулируется стабильный API механизма):

Хрестоматийный пример шаблона, для упрощения изложения приведён вариант без параметров запроса:

ВЫБРАТЬ РАЗЛИЧНЫЕ
	Сотрудники.Ссылка КАК Сотрудник,
	ДАТАВРЕМЯ(2025, 11, 1) КАК Период
ПОМЕСТИТЬ ВТСотрудники
ИЗ
	Справочник.Сотрудники КАК Сотрудники
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	ЗНАЧЕНИЕ(Справочник.Сотрудники.ПустаяСсылка) КАК Сотрудник,
	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК Организация,
	ЗНАЧЕНИЕ(Справочник.Должности.ПустаяСсылка) КАК Должность,
	ЗНАЧЕНИЕ(Справочник.ГрафикиРаботыСотрудников.ПустаяСсылка) КАК ГрафикРаботы,
	ДАТАВРЕМЯ(1, 1, 1) КАК ДатаПриема,
	ДАТАВРЕМЯ(1, 1, 1) КАК ДатаУвольнения
ПОМЕСТИТЬ Представления_КадровыеДанныеСотрудников
ИЗ
	ВТСотрудники КАК ВТСотрудники
ГДЕ
	"ТолькоРазрешенные" = ИСТИНА
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ * ИЗ Представления_КадровыеДанныеСотрудников

Запрос-пустышка с выражением "ПОМЕСТИТЬ Представления_..." - это и есть шаблон, который будет преобразован в реальный запрос на создание временной таблицы с обращением только к нужным данным. Таких шаблонов в один запрос можно вставить много. Если нужно несколько эксземпляров одного и того же представления с разными отборами или составом полей, то требуется к имени ВТ добавлять ещё и суффикс, например "Представления_КадровыеДанныеСотрудников_БездельникиНачальники", "Представления_КадровыеДанныеСотрудников_РеальныеТрудяги".

Как и во всех подобных статьях, здесь Представления_КадровыеДанныеСотрудников появился как рояль в кустах, но я потом ниже приведу список типовых представлений из ЗУП с описаниями доступных полей и параметров (постараюсь дополнять список периодически).

Первый запрос на создание ВТСотрудники - это параметр создания представления, в примере - это все сотрудники на фиксированную дату. Здесь вы вольны написать свою логику отбора - как нужно вам. И, кстати, не обязательно все записи на одну дату. Связь между параметром и запросом с представлениями определяется выражением ИЗ ВТСотрудники КАК ВТСотрудники.

Неграмотный отбор ГДЕ "ТолькоРазрешенные" = ИСТИНА предназначен не для выполнения на языке запросов 1С, а для передачи в процедуру формирования запросов в качестве параметра, т.е. это параметр для выполняемого кода, в реальном запросе такого брейнфака конечно не будет.

Минимально необходимой код для выполнения, если у СКД нет параметров:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	ЗарплатаКадрыОбщиеНаборыДанных.ЗаполнитьОбщиеИсточникиДанныхОтчета(ЭтотОбъект);
КонецПроцедуры

В большинстве случаев параметры конечно есть и код нужно хорошенько обмазать хорошо известными заклинаниями:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	// вот оно, ключевой вызов тут:
	ЗарплатаКадрыОбщиеНаборыДанных.ЗаполнитьОбшиеИсточникиДанныхОтчета(ЭтотОбъект);
	
	// далее заполнение настроек, источников данных и т.д. как обычно:

	НастройкиОтчета = КомпоновщикНастроек.ПолучитьНастройки();
	МакетКомпоновки = МакетКомпоновкиДанных(СхемаКомпоновкиДанных, НастройкиОтчета, ДанныеРасшифровки);
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , ДанныеРасшифровки, Истина);

	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновки, Истина);

КонецПроцедуры

Также для работы с настройками необходимо инициализировать СКД до выполнения главного запроса, поэтому в модуль отчёта СКД кроме вышеуказанного кода возможно потребуется добавить ещё:

Перем ОтчетИнициализирован;

Процедура ИнициализироватьОтчет() Экспорт
	Если Не ОтчетИнициализирован Тогда
		// снова тот же ключевой вызов:
		ЗарплатаКадрыОбщиеНаборыДанных.ЗаполнитьОбшиеИсточникиДанныхОтчета(ЭтотОбъект);
	КонецЕсли;
КонецПроцедуры

Процедура ПередЗагрузкойНастроекВКомпоновщик (Контекст, КлючСхемы, КлючВарианта, НовыеПользовательскиеНастройкиКД) Экспорт
	Если КлючСхемы <> "СхемаИнициализирована" Тогда
		ИнициализироватьОтчет();
		КлючСхемы = "СхемаИнициализирована";
	КонецЕсли;
КонецПроцедуры

ОтчетИнициализирован = Ложь;

Как применять механизм представлений при формировании любого запроса

У разработчика и аналитика может сложиться впечатление, что механизм представлений предназначен исключительно для отчётов на СКД. Большинство так и считают.

Это заблуждение - механизм представлений можно использовать в любом месте программы, где есть потребность написать эффективный запрос:

Формирование реального запроса делается одной командой:

Запрос = Новый Запрос("ВЫБРАТЬ ........."); // запрос с шаблонами-представлениями
ЗарплатаКадрыОбщиеНаборыДанных.ЗаменитьЗапросыКПредставлениямВиртуальныхТаблиц(Запрос.Текст);
Выборка = Запрос.Выполнить().Выбрать();

Здесь ожидался длинный параграф с простыней кода, по факту оказался самым коротким 😄. Далее список представлений с описанием параметров и полей:

Представления_Периоды

Формирует таблицу с периодами, например по всем дням месяца. Под капотом находится вызов функции ЗарплатаКадрыОбщиеНаборыДанных.ЗапросВТПериоды:

ВЫБРАТЬ
	ДАТАВРЕМЯ(1, 1, 1) КАК Период
ПОМЕСТИТЬ Представления_Периоды
ГДЕ
	"НачалоИнтервала" = &НачалоИнтервала
	И "ОкончаниеИнтервала" = &ОкончаниеИнтервала
	И "Периодичность" = "ДЕНЬ"  // ГОД, КВАРТАЛ, МЕСЯЦ, ДЕНЬ
	И "ИспользоватьКонецПериода" = ЛОЖЬ
;

Каких-либо других полей для выбора и параметров нет. Полученную таблицу можно использовать для формирования других представлений как один из входящих параметров.

Представления_КадровыеДанныеСотрудников

Под капотом находится вызов функции КадровыйУчет.ЗапросВТКадровыеДанныеСотрудников. Отбор кадровых данных производится по таблице ВТСотрудники, которую вы можете сформировать произвольным образом - главное чтобы она содержала обязательные поля "Сотрудник" и "Период" (наличие других полей не возбраняется). В таблицу представления будут собраны данные по выбранным сотрудникам на указанные даты:

ВЫБРАТЬ РАЗЛИЧНЫЕ
	Сотрудники.Ссылка КАК Сотрудник,
	&Период КАК Период
ПОМЕСТИТЬ ВТСотрудники
ИЗ
	Справочник.Сотрудники КАК Сотрудники
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	ДАТАВРЕМЯ(1, 1, 1) КАК Период,
	ЗНАЧЕНИЕ(Справочник.Сотрудники.ПустаяСсылка) КАК Сотрудник,
	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК Организация,
	ЗНАЧЕНИЕ(Справочник.Должности.ПустаяСсылка) КАК Должность
ПОМЕСТИТЬ Представления_КадровыеДанныеСотрудников
ИЗ
	ВТСотрудники КАК ВТСотрудники
ГДЕ
	"ТолькоРазрешенные" = ИСТИНА
	И "ФормироватьСПериодичностьДень" = ИСТИНА
;

Представления_КадровыеДанныеФизическихЛиц

Под капотом находится вызов функции КадровыйУчет.ЗапросВТКадровыеДанныеФизическихЛиц. Отбор данных производится по таблице ВТФизическиеЛица, которую вы можете сформировать произвольным образом - главное чтобы она содержала обязательные поля "ФизическоеЛицо" и "Период" (наличие других полей не возбраняется). В таблицу представления будут собраны данные по выбранным физлицам на указанные даты:

ВЫБРАТЬ РАЗЛИЧНЫЕ
	ФизическиеЛица.Ссылка КАК ФизическоеЛицо,
	&Период КАК Период
ПОМЕСТИТЬ ВТФизическиеЛица
ИЗ
	Справочник.ФизическиеЛица КАК ФизическиеЛица
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	ДАТАВРЕМЯ(1, 1, 1) КАК ДатаРождения,
	"" КАК ИНН,
	"" КАК СтраховойНомерПФР,
	NULL КАК Пол,
	"" КАК АдресПоПропискеПредставление
ПОМЕСТИТЬ Представления_КадровыеДанныеФизическихЛиц
ИЗ
	ВТФизическиеЛица КАК ВТФизическиеЛица
ГДЕ
	"ТолькоРазрешенные" = ИСТИНА
;

В этом представлении недоступна кадровая информация по сотруднику (нет полей Сотрудник, Должность, Подразделение и т.д.)

Представления_СотрудникиОрганизации

Под капотом находится вызов функции КадровыйУчет.ЗапросВТСотрудникиОрганизации. В отличии от вышеописанных представлений отбор данных осуществляется не на дату, а внутри заданного периода, т.е. если отбирать список за месяц, то в результат попадут также и принятые на работу в этом месяце и уволенные в этом месяце. Таким образом, если два вышеописанных представления являются "остаточными", то этот получается "оборотный". Также опционально присутствуют отборы по организации, подразделению. Всё это оптимально подходит для заполнения ТЧ документов. Если цель - получить всех работавших в периоде, то создавать ВТФизическиеЛица не нужно и выражение ИЗ ВТФизическиеЛица КАК ВТФизическиеЛица следует исключить из шаблона:

ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ФизическиеЛица.Ссылка КАК ФизическоеЛицо
ПОМЕСТИТЬ ВТФизическиеЛица
ИЗ
	Справочник.ФизическиеЛица КАК ФизическиеЛица
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ДАТАВРЕМЯ(1, 1, 1) КАК ДатаПриема,
	ДАТАВРЕМЯ(1, 1, 1) КАК ДатаУвольнения,
	ЗНАЧЕНИЕ(Справочник.Должности.ПустаяСсылка) КАК Должность,
ПОМЕСТИТЬ Представления_СотрудникиОрганизации
ИЗ
	ВТФизическиеЛица КАК ФизическиеЛица
ГДЕ
	"ТолькоРазрешенные" = ИСТИНА
	И "ОтбиратьПоГоловнойОрганизации" = ЛОЖЬ
	И "НачалоПериода" = &НачалоПериода
	И "ОкончаниеПериода" = &ОкончаниеПериода
	И "Организация" = &Организация
	И "Подразделение" = &Подразделение
;

Если не используется СКД, то полученный запрос требует установки 3-х обязательных параметров, пример:

Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
	|	ДАТАВРЕМЯ(1, 1, 1) КАК Период,
	|	ЗНАЧЕНИЕ(Справочник.Сотрудники.ПустаяСсылка) КАК Сотрудник,
	|	ЗНАЧЕНИЕ(Справочник.ФизическиеЛица.ПустаяСсылка) КАК ФизическоеЛицо,
	|	"""" КАК Возраст,
	|	ДАТАВРЕМЯ(1, 1, 1) КАК ДатаПриема,
	|	ДАТАВРЕМЯ(1, 1, 1) КАК ДатаУвольнения,
	|	ЗНАЧЕНИЕ(Справочник.Должности.ПустаяСсылка) КАК Должность,
	|	ЗНАЧЕНИЕ(Справочник.РабочиеМестаОхраныТруда.ПустаяСсылка) КАК РабочееМестоОхраныТруда,
	|	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК ГоловнаяОрганизация,
	|	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК Организация,
	|	ЗНАЧЕНИЕ(Справочник.ПодразделенияОрганизаций.ПустаяСсылка) КАК Подразделение,
	|	ЗНАЧЕНИЕ(Перечисление.ВидыЗанятости.ПустаяСсылка) КАК ВидЗанятости
	|ПОМЕСТИТЬ Представления_СотрудникиОрганизации
	|ГДЕ
	|	""ТолькоРазрешенные"" = ИСТИНА
	|	И ""Организация"" = &Организация
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ * ИЗ Представления_СотрудникиОрганизации";

// Формирует реальные запросы по представлениям:
ЗарплатаКадрыОбщиеНаборыДанных.ЗаменитьЗапросыКПредставлениямВиртуальныхТаблиц(Запрос.Текст);

// Обязательные параметры:
Запрос.УстановитьПараметр("ВТРабочиеМестаСотрудниковДляВТСотрудникиОрганизации_Параметр1", Истина);
Запрос.УстановитьПараметр("ВТРабочиеМестаСотрудниковДляВТСотрудникиОрганизации_Параметр2", Перечисления.ВидыКадровыхСобытий.Увольнение);
Запрос.УстановитьПараметр("РольСотрудника_ВТРабочиеМестаСотрудниковДляВТСотрудникиОрганизации", Перечисления.РолиСотрудников.Работник);

// Наш отбор по организации
Запрос.УстановитьПараметр("Организация", Справочники.Организации.НайтиПоРеквизиту("ИНН", "2345678901"));

Результат = Запрос.Выполнить().Выгрузить();

Список доступных полей такой же, как у Представления_КадровыеДанныеСотрудников

Представления_РабочиеМестаСотрудников

Под капотом находится вызов функции КадровыйУчет.ЗапросВТРабочиеМестаСотрудниковПоВременнойТаблице. Отбор данных осуществляется по временной таблице, в которой обязательно должны быть поля "Сотрудник", "НачалоПериода" и "ОкончаниеПериода":

ВЫБРАТЬ РАЗРЕШЕННЫЕ
	Сотрудники.Ссылка КАК Сотрудник,
	&ДатаНачала КАК НачалоПериода,
	&ДатаОкончания КАК ОкончаниеПериода
ПОМЕСТИТЬ ВТСотрудникиПериоды
ИЗ
	Справочник.Сотрудники КАК Сотрудники
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ДАТАВРЕМЯ(1, 1, 1) КАК Период,
	ДАТАВРЕМЯ(1, 1, 1) КАК Год,
	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК ГоловнаяОрганизация,
	ЗНАЧЕНИЕ(Справочник.Сотрудники.ПустаяСсылка) КАК ГоловнойСотрудник,
	ЗНАЧЕНИЕ(Справочник.ШтатноеРасписание.ПустаяСсылка) КАК ДолжностьПоШтатномуРасписанию,
	0 КАК КоличествоСтавок
ПОМЕСТИТЬ Представления_РабочиеМестаСотрудников
ИЗ
	ВТСотрудникиПериоды КАК ВТСотрудникиПериоды
ГДЕ
	"ТолькоРазрешенные" = ИСТИНА
	И "Организация" = &Организация
	И "Подразделение" = &Подразделение
;

Сформированный реальный запрос требует установки обязательных параметров (см. пример выше для "Представления_СотрудникиОрганизации"), есть небольшое отличие в наименовании параметров:

// Обязательные параметры:
Запрос.УстановитьПараметр("ПредставленияРабочиеМестаСотрудников_Параметр1", Истина);
Запрос.УстановитьПараметр("ПредставленияРабочиеМестаСотрудников_Параметр2", Перечисления.ВидыКадровыхСобытий.Увольнение);
Запрос.УстановитьПараметр("РольСотрудника_ПредставленияРабочиеМестаСотрудников", Перечисления.РолиСотрудников.Работник);

Представления_ШтатноеРасписание

Под капотом находится вызов функции УправлениеШтатнымРасписанием.ЗапросПредставленияШтатноеРасписание. Отбор данных осуществляется передачей параметров через секцию запроса ГДЕ:

ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 0
	ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка) КАК Организация,
	ЗНАЧЕНИЕ(Справочник.ШтатноеРасписание.ПустаяСсылка) КАК ПозицияШтатногоРасписания,
	ЗНАЧЕНИЕ(Справочник.ПодразделенияОрганизаций.ПустаяСсылка) КАК Подразделение,
	ЗНАЧЕНИЕ(Справочник.Должности.ПустаяСсылка) КАК Должность,
	ЗНАЧЕНИЕ(Справочник.РазрядыКатегорииДолжностей.ПустаяСсылка) КАК РазрядКатегория,
	ЗНАЧЕНИЕ(Справочник.ГрафикиРаботыСотрудников.ПустаяСсылка) КАК ГрафикРаботыСотрудников,
	0 КАК КоличествоСтавок
	0 КАК ФОТ,
ПОМЕСТИТЬ Представления_ШтатноеРасписание
ГДЕ
	"ТолькоРазрешенные" = ИСТИНА
	И "ДатаАктуальности" = &ДатаАктуальности
	И "ВключатьНачисления" = ЛОЖЬ
	И "ВключаяЗакрытые" = ИСТИНА
;

В чём заключается смысл заклинания ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 0 мне неведомо, но работает оно именно так.